Description: This script will link files to events in iCal
Requirement: iCal Mac OS 10.3.x
Open in the Script Editor

-- Script Start
(*
  A script to link files to events in iCal
  Inspiration from
  http://www.macosxhints.com/article.php?story=20040204213328956
  2004-02-14 by Fredrik Jonsson <mailto(colon)fredrik(at)combonet(dot)se>
  home page <http://xdeb.org/wiki/AppleScript>
*)
 
try
  tell application "Finder"
    set added_item to selection as alias
    set this_info to (info for added_item)
    set the file_name to the name of this_info as string
  end tell
  tell application "System Events"
    set ical_url to (URL of added_item) as string
  end tell
  scheduleMeeting(file_name, ical_url)
on error
  beep
  tell me to display dialog "You need to select one single file in the Finder." with icon 2 buttons {"OK"} default button 1
end try
 
on scheduleMeeting(this_name, this_url)
  tell application "iCal"
    set theItem to (make new event at end of events of calendar 1)
    tell theItem
      set summary to "File name: " & this_name
      set url to this_url
      set status to tentative
      set end date to (current date) + 60 * minutes as date
      make new display alarm at beginning of display alarms with properties {trigger interval:-60}
    end tell
    activate
    show theItem
  end tell
end scheduleMeeting
-- Script Stop